home *** CD-ROM | disk | FTP | other *** search
/ Shareware Grab Bag / Shareware Grab Bag.iso / 011 / xlt86.lbr / XLT86.AQM / XLT86.ASM
Assembly Source File  |  1979-12-31  |  41KB  |  2,769 lines
  1. ;*******************************************************
  2. ;
  3. ;            XLT86
  4. ;
  5. ; Translates Intel 8080 assembly language source code
  6. ;  to Intel 8086 assembly language source code.
  7. ;
  8. ; 11/11/84 Frank J. Zerilli
  9. ;
  10. VERS    EQU    106
  11. ;
  12. ;*******************************************************
  13. ;
  14. ;      XLT86 processes lines with the exclamation point
  15. ; statement separator correctly.  It strips trailing
  16. ; blanks or tabs from lines.  It replaces initial
  17. ; asterisks in lines with semicolons.  It provides
  18. ; several options to format the output file for best
  19. ; appearance.
  20. ; 
  21. ;      This program gives the choice of converting the
  22. ; case of instructions to upper or lower case or of
  23. ; trying to preserve the case of instructions.
  24. ; 
  25. ;      An activity dot is printed on the console for
  26. ; every 100 lines of input processed.
  27. ; 
  28. ;
  29. ; 
  30. ; Command line:
  31. ;
  32. ;     XLT86 [d:]srcfile[.typ] [d:destfile.typ]
  33. ;
  34. ;      All parameters in brackets are optional, and, if
  35. ; omitted, the default values are:
  36. ;
  37. ;  Source file-type      -- ASM
  38. ;  Destination file-type -- A86
  39. ;  Destination file-name -- same as the source file-name
  40. ;  Drive                 -- current drive
  41. ;
  42. ; FLAG LOCATIONS:
  43. ;
  44. ; 103H -- Change to non-zero value to suppress
  45. ;      translation of several non-standard opcodes:
  46. ;      REQ, RNE, RLT, RGE, CEQ, CNE, CLT, CGE
  47. ;      JEQ, JNE, JLT, JGE,
  48. ;      ENT, NAM, RAM, ROG, IFC, ICL, LST, MAC
  49. ;
  50. ; 104H -- If non-zero (default) XLT86 converts lines
  51. ;      with multiple statements separated by DR's EP
  52. ;      separator into separate lines.
  53. ;      Change to zero for output on a single line
  54. ;      with the translated statements separated by
  55. ;      EP.
  56. ;
  57. ; 107H--  If zero (default) XLT86 translates
  58. ;
  59. ;        PUSH PSW    POP PSW
  60. ;
  61. ;      to
  62. ;
  63. ;        LAHF        POP AX
  64. ;        PUSH AX        SAHF
  65. ;
  66. ;      Otherwise, the translation is
  67. ;
  68. ;        LAHF        POP AX
  69. ;        XCHG AH,AL    XCHG AH,AL
  70. ;        PUSH AX        SAHF
  71. ;        XCHG AH,AL
  72. ;
  73. ; 108H-- If zero (default) XLT86 translates
  74. ;
  75. ;        INX rp        DCX rp
  76. ;
  77. ;     to
  78. ;
  79. ;        INC rp'        DEC rp'
  80. ;
  81. ;     Otherwise, the translation is
  82. ;
  83. ;        PUSHF        PUSHF
  84. ;        INC rp'        DEC rp'
  85. ;        POPF        POPF
  86. ;
  87. ; 109H-- If zero (default) XLT86 translates
  88. ;
  89. ;        DAD rp
  90. ;
  91. ;     to
  92. ;
  93. ;        ADD BX,rp'
  94. ;
  95. ;     Otherwise, the translation is
  96. ;
  97. ;        PUSHF
  98. ;        ADD BX,rp'
  99. ;        POPF
  100. ;
  101.  
  102. N00    EQU    0
  103. N01    EQU    1
  104. ;
  105. N07    EQU    7
  106. N09    EQU    9    ;tab every 8th col.
  107. NF8    EQU    0F8H    ;mod 8
  108. ;
  109. LBUFLN    EQU    80    ;line buffer length
  110. OPBFLN    EQU    5    ;opcode buffer length
  111. MEMSIZ    EQU    4    ;memory available in Kb
  112. IBNUM    EQU    4*MEMSIZ
  113. OBNUM    EQU    4*MEMSIZ
  114. RECLEN    EQU    128    ;
  115. STCKLN    EQU    128    ;stack size
  116. IBFLEN    EQU    IBNUM*RECLEN
  117. OBFLEN    EQU    OBNUM*RECLEN
  118. ;
  119. CTRLC    EQU    3
  120. EOT    EQU    4
  121. BEL    EQU    7
  122. HT    EQU    9
  123. LF    EQU    0AH
  124. CR    EQU    0DH
  125. ESC    EQU    1BH
  126. QUOTE    EQU    27H
  127. ;
  128. ABORT    EQU    0000
  129. BDOS    EQU    0005
  130. DFCB1    EQU    005CH
  131. DFCB2    EQU    006CH
  132. ;
  133. FNLEN    EQU    8
  134. EOS    EQU    EOT    ; replacement for exclamation pt
  135. EOF    EQU    1AH
  136. NFF    EQU    0FFH    ;disk error return
  137. ;
  138. ;    BDOS FUNCTIONS
  139. ;
  140. nCIN    EQU    1
  141. nCOUT    EQU    2
  142. nCDAV    EQU    0BH
  143. nOPEN    EQU    0FH
  144. nCLOSE    EQU    10H
  145. nDEL    EQU    13H
  146. nRDNR    EQU    14H
  147. nWRNR    EQU    15H
  148. nCREAT    EQU    16H
  149. nCDISK    EQU    19H
  150. nDMA    EQU    1AH
  151. ;
  152. ;
  153.     ORG    100H
  154. ;
  155.     JMP    START
  156. ;
  157. ; OPTION FLAGS
  158. ;
  159. PSEFLG    DB    0    ;(103H) 0 to translate non-
  160.             ;  standard opcodes
  161. MLTLFL    DB    0FFH    ;(104H) 0 to put input line with
  162.             ;  exc. pt. to output on one line
  163. TCASFL    DB    0    ;(105H) 0 to preserve case
  164.             ;
  165. LCASFL    DB    0    ;(106H) 0 for upper case if
  166.             ;  TCASFL not zero
  167. PSWFL    DB    0    ;(107H) non-zero to preserve 8080
  168.             ;  order of PSW registers on stack
  169. INXFL    DB    0    ;(108H) non-zero to preserve flags
  170.             ;  with INX and DCX translations
  171. DADFL    DB    0    ;(109H) non-zero to preserve flags
  172.             ;  with DAD translation
  173. ;
  174. ;  HELP MESSAGE
  175. ;
  176. HMSG1:
  177.  
  178.  DB CR,LF
  179.  DB LF
  180.  DB 'XLT86 translates Intel 8080 assembly language source',CR,LF
  181.  DB 'code into Intel 8086 assembly language source code.',CR,LF
  182.  DB LF
  183.  DB 'It is invoked by a command of the form:',CR,LF
  184.  DB LF
  185.  DB '    XLT86 [d:]srcfile[.typ] [d:destfile.typ]',CR,LF
  186.  DB LF
  187.  DB 'The brackets denote optional parameters and the ',CR,LF
  188.  DB 'default values are:',CR,LF
  189.  DB LF
  190.  DB '    Source file-type      --  ASM',CR,LF
  191.  DB '    Destination file-type --  A86',CR,LF
  192.  DB '    Destination file-name --  same as source file-name',CR,LF
  193.  DB '    Drive                 --  current drive',CR,LF
  194.  DB CR,LF
  195.  DB 'Press any key to continue - ',0
  196.  
  197. HMSG2:
  198.  
  199.  DB CR,LF
  200.  DB LF
  201.  DB 'Examples:',CR,LF
  202.  DB LF
  203.  DB 'XLT86 PRGM1               --translates PRGM1.ASM to PRGM1.A86',CR,LF
  204.  DB 'XLT86 PRGM1 PRGM2         --translates PRGM1.ASM to PRGM2.A86',CR,LF
  205.  DB 'XLT86 PRGM1.TXT PRGM2.MAC --translates PRGM1.TXT to PRGM2.MAC',CR,LF
  206.  DB LF
  207.  DB 'XLT86 also has the following features:',CR,LF
  208.  DB LF
  209.  DB 'Case will be preserved as well as possible -- if an opcode has',CR,LF
  210.  DB 'a lower case character, the translated opcode will be in lower',CR,LF
  211.  DB 'case.',CR,LF
  212.  DB LF
  213.  DB 'All asterisks at the beginning of lines will be replaced with',CR,LF
  214.  DB 'semicolons.',CR,LF
  215.  DB LF
  216.  DB 'A dot is printed on the console for every 100 lines of input ',CR,LF
  217.  DB 'processed.',CR,LF
  218.  DB LF
  219.  DB 0
  220. ;
  221. ;=============================================================================
  222. ;
  223. ; Program begins here
  224. ;
  225. START:
  226.     LXI    H,0
  227.     DAD    SP
  228.     SHLD    SPBDOS
  229.  
  230.     LXI    SP,STACK
  231.  
  232.     LDA    DFCB1+1    ; check for a file name
  233.     CPI    ' '    ; print help if no name
  234.     JNZ    BEGIN    ; no help requested
  235.     LXI    D,SIGNON
  236.     CALL    PRTLIN
  237.     LXI    D,HMSG1    ; print help message
  238.     CALL    PRTLIN
  239.     MVI    C,nCIN    ; wait for any character
  240.     CALL    BDOS
  241.     LXI    D,HMSG2    ; print rest of help
  242.     CALL    PRTLIN
  243.     LHLD    SPBDOS    ; retrieve system stack
  244.     SPHL        ;  pointer and pop
  245.     RET        ;  to PC
  246.  
  247. BEGIN:    CALL    HELLO    ;signon, open in & out files
  248. NXTLIN:    CALL    GETLIN    ;get line from input file to buf
  249.     CALL    PROCLIN    ; process line
  250.     JMP    NXTLIN
  251. ;
  252. ;
  253. ;
  254.  
  255. ;*******************************************************
  256. ;
  257. ;    Print signon, open input
  258. ;    and output files.
  259. ;
  260. HELLO:    LXI    D,SIGNON
  261.     CALL    PRTLIN
  262. HELLO0:    MVI    A,'D'    ; translate DB & EQU (for
  263.     STA    OPTBDB    ;  uniform formatting)
  264.     MVI    A,HT    ; Default is tab after opcode
  265.     STA    MLTSPC    ;  for stmts on separate lines
  266.     MVI    A,HT    ; HT after opcode
  267.     STA    PUTHT+1
  268.     MVI    A,41    ; tab comments to col 33
  269.     STA    PUTND5+1
  270.     MVI    A,0FEH    ; CP instruction
  271.     STA    EXCLAM
  272.     XRA    A
  273.     STA    TCASFL    ; don't convert case
  274.     STA    LCASFL    ; lower case flag
  275.     LXI    H,NEWLSP
  276.     SHLD    SEPMSG
  277.  
  278.     LDA    PSEFLG    ; translate non-standard
  279.     ORA    A    ;  opcodes ?
  280.     CNZ    NXPSD
  281.  
  282.     LXI    D,DBMSG
  283.     CALL    PRTLIN    ;
  284.     CALL    CHKYES    ; xlat DB & EQU ?
  285.     CPI    ESC
  286.     JZ    HELLO0
  287.     CPI    CTRLC
  288.     JZ    ABORT
  289.     CPI    'Y'
  290.     CNZ    NXDBEQ
  291.  
  292.     LDA    MLTLFL    ; force space after opcode
  293.     ORA    A    ;  if MLTLFL not set
  294.     JZ    HELLO2
  295.     LXI    D,SPCMSG
  296.     CALL    PRTLIN    ; use space after
  297.     CALL    CHKYES    ; opcode ?
  298.     CPI    ESC
  299.     JZ    HELLO0
  300.     CPI    CTRLC
  301.     JZ    ABORT
  302.     CPI    'Y'
  303. HELLO2:    CZ    SETSPC
  304.  
  305.     LXI    D,COLMSG
  306.     CALL    PRTLIN    ;
  307.     CALL    CHKYES    ; start comment
  308.     CPI    ESC
  309.     JZ    HELLO0
  310.     CPI    CTRLC
  311.     JZ    ABORT
  312.     CPI    'Y'
  313.     CZ    SETCOL    ; in column 25 ?
  314.  
  315.     LXI    D,EXCMSG
  316.     CALL    PRTLIN    ; Ignore exclamation point
  317.     CALL    CHKYES    ;  separator ?
  318.     CPI    ESC
  319.     JZ    HELLO0
  320.     CPI    CTRLC
  321.     JZ    ABORT
  322.     CPI    'Y'
  323.     CZ    SETNEX
  324.  
  325.     LXI    D,MLTMSG
  326.     CALL    PRTLIN    ; multiple statements
  327.     CALL    CHKYES    ; on one line ?
  328.     CPI    ESC
  329.     JZ    HELLO0
  330.     CPI    CTRLC
  331.     JZ    ABORT
  332.     CPI    'Y'
  333.     CZ    SETMLT
  334.  
  335.     LXI    D,TRNMSG ; Convert case ?
  336.     CALL    PRTLIN
  337.     CALL    CHKYES
  338.     CPI    ESC
  339.     JZ    HELLO0
  340.     CPI    CTRLC
  341.     JZ    ABORT
  342.     CPI    'L'
  343.     CZ    SETLC
  344.     CPI    'U'
  345.     CZ    SETUC
  346.  
  347.     MVI    A,N01
  348.     STA    COLNUM
  349.  
  350.     MVI    C,nCDISK
  351.     CALL    BDOS
  352.     INR    A
  353.     STA    xCDISK
  354.  
  355.     CALL    MAKFNS
  356.     CALL    OPENIN
  357.     CALL    CREATO
  358.     RET
  359. ;
  360. SIGNON    DB    '8080-to-8086 Translator version '
  361.     DB    VERS/100+'0','.',(VERS MOD 100)/10+'0'
  362.     DB    (VERS MOD 10)+'0'
  363.     DB    CR,LF,0
  364. ;
  365. ; Don't translate non-standard opcodes
  366. ;
  367. NXPSD:    XRA    A
  368.     STA    OPTTDL
  369.     STA    OPTENT
  370.     STA    OPTIFC
  371.     RET
  372.  
  373. DBMSG    DB    'Translate DB & EQU ? '
  374.     DB    '[Y/ret=N/esc/^C] ',0
  375. ;
  376. NXDBEQ:    XRA    A
  377.     STA    OPTBDB
  378.     RET
  379. ;
  380. SPCMSG    DB    'Use space (default TAB) after opcode ? '
  381.     DB    '[Y/ret=N/esc/^C] ',0
  382. ;
  383. SETSPC:    LXI    H,PUTHT+1
  384.     MVI    A,' '
  385.     MOV    M,A
  386.     STA    MLTSPC
  387.     RET
  388. ;
  389. COLMSG    DB    'Start comment in column 25 (default 33) ? '
  390.     DB    '[Y/ret=N/esc/^C] ',0
  391. ;
  392. SETCOL:    LXI    H,PUTND5+1
  393.     MVI    A,33
  394.     MOV    M,A
  395.     RET
  396. ;
  397. EXCMSG    DB    'Ignore ! statement separator ? '
  398.     DB    '[Y/ret=N/esc/^C] ',0
  399. ;
  400. SETNEX:    MVI    A,0C9H    ; RET instruction
  401.     STA    EXCLAM
  402.     RET
  403. ;
  404. MLTMSG    DB    'Put opcodes converted to multiple'
  405.     DB    ' statements on one line ? '
  406.     DB    '[Y/ret=N/esc/^C] ',0
  407. ;
  408. SETMLT:    LXI    H,EXCLSP
  409.     SHLD    SEPMSG
  410.     MVI    A,' '
  411.     STA    MLTSPC
  412.     RET
  413.  
  414. ;
  415. TRNMSG    DB    'Translate instructions to Upper/Lower'
  416.     DB    ' or preserve case ? [U/L/ret/esc/^C] ',0
  417. ;
  418. SETLC:    STA    TCASFL
  419.     STA    LCASFL
  420.     RET
  421. ;
  422. SETUC:    STA    TCASFL
  423.     RET
  424.  
  425. ;*******************************************************
  426. ;
  427. ;    Gets line from input file to line
  428. ;    buffer until CR.  Filters out ctrl
  429. ;    chars except for HT.  Truncates
  430. ;    lines after LBUFLN chars.
  431. ;    Terminates line with CR, LF, 0.
  432. ;
  433. GETLIN:    CALL    PDOT    ; print activity dot
  434.     CALL    CHKIN
  435.     CPI    CTRLC
  436.     JZ    JABORT
  437.     XRA    A
  438.     STA    QUOTFL    ; not in quote
  439.     STA    CMNTFL    ; not in comment
  440.     LXI    H,LBUFF    ;line buffer
  441.     MVI    B,LBUFLN ;max # of char
  442. GETLN1:    XCHG
  443.     LHLD    xIBUFF
  444.     XCHG
  445.  
  446.     MOV    A,D
  447.     CPI    (IBUFF+IBFLEN)/256
  448.     JNZ    GETLN4
  449.     MOV    A,E
  450.     CPI    (IBUFF+IBFLEN) MOD 256
  451.  
  452.     JNZ    GETLN4
  453.     PUSH    B
  454.     PUSH    H
  455.     LXI    D,IBUFF
  456. GETLN2:    MVI    C,nDMA
  457.     PUSH    D
  458.     CALL    BDOS
  459.     POP    D
  460.  
  461.     XCHG
  462.  
  463.     LXI    D,INFCB
  464.     MVI    C,nRDNR
  465.     PUSH    H
  466.     CALL    BDOS
  467.     POP    H
  468.     DCR    A
  469.     JNZ    GETLN3
  470.     MVI    A,EOF
  471.     MOV    M,A
  472. GETLN3:    LXI    D,RECLEN
  473.     DAD    D
  474.     XCHG
  475.     MOV    A,D
  476.     CPI    (IBUFF+IBFLEN)/256
  477.     JNZ    GETLN2
  478.     MOV    A,E
  479.     CPI    (IBUFF+IBFLEN) MOD 256
  480.     JNZ    GETLN2
  481.  
  482.     POP    H
  483.     POP    B
  484.     LXI    D,IBUFF
  485. GETLN4:    LDAX    D
  486.     INX    D
  487.     XCHG
  488.     SHLD    xIBUFF
  489.     XCHG
  490.     MOV    M,A
  491.  
  492.     CPI    QUOTE    ; set or reset
  493.     JNZ    GTLN41    ;  QUOTFL
  494.     LDA    QUOTFL
  495.     CMA
  496.     STA    QUOTFL
  497.  
  498. GTLN41:    MOV    A,M    ; Translate exclam.  pt.
  499.     CALL    EXCLAM    ;  which is not in quote
  500.     MOV    M,A    ;  to EOS
  501.  
  502.     LDA    TCASFL    ; translate to upper
  503.     ORA    A    ;  or lower case ?
  504.     JZ    GTLN46    ; NO
  505.  
  506.     LDA    QUOTFL    ; if in quote, do
  507.     ORA    A    ;  nothing
  508.     JNZ    GTLN43
  509.     MOV    A,M    ; otherwise, ';' sets
  510.     CPI    ';'    ;  CMNTFL and EOS resets
  511.     JZ    GTLN42    ;  it
  512.     CPI    EOS
  513.     JNZ    GTLN43
  514.     XRA    A
  515. GTLN42:    STA    CMNTFL
  516.  
  517. GTLN43:    LDA    QUOTFL    ; If in quote,
  518.     ORA    A    ;  do nothing
  519.     JNZ    GTLN46
  520.     LDA    CMNTFL    ; If in comment,
  521.     ORA    A    ;  do nothing
  522.     JNZ    GTLN46
  523.     LDA    LCASFL    ; Otherwise,
  524.     ORA    A    ;  if LCASFL set
  525.     MOV    A,M
  526.     JZ    GTLN44
  527.     CALL    LCASE    ;  trns to lwr case
  528.     JMP    GTLN45
  529. GTLN44:    CALL    UCASE    ;  else trns to upr case
  530. GTLN45:    MOV    M,A
  531.  
  532. GTLN46:    MOV    A,M
  533.     CPI    CR
  534.     JZ    GETLN6
  535.     CPI    HT    ; filters out all ctrl
  536.     JZ    GETLN5    ; chars except tab
  537.  
  538.     CPI    EOF
  539.     JZ    GETLN7
  540.     CPI    EOS
  541.     JZ    GETLN5
  542.  
  543.     CPI    ' '
  544.     JC    GETLN1
  545. GETLN5:    DCR    B
  546.     INX    H
  547.     JNZ    GETLN1
  548.     INR    B
  549.     DCX    H
  550.     JMP    GETLN1
  551. ;
  552. GETLN6:    INX    H
  553.     MVI    M,LF
  554.     INX    H
  555.     MVI    M,N00
  556.     XCHG
  557.     SHLD    xIBUFF
  558.     XCHG
  559.     RET
  560.  
  561. ;
  562. ;    Change exclamation point to EOS in A
  563. ;
  564. EXCLAM:    CPI    '!'
  565.     RNZ
  566.     LDA    QUOTFL
  567.     ORA    A
  568.     MVI    A,'!'
  569.     RNZ
  570.     MVI    A,EOS
  571.     RET
  572. ;
  573. QUOTFL    DB    0
  574. CMNTFL    DB    0
  575.  
  576. ;
  577. ;    Exit
  578. ;
  579. GETLN7:    CALL    CLOSEO
  580.     LXI    D,UPSMSG
  581.     CALL    PRTLIN
  582.     LXI    D,ENDIFL
  583.     CALL    PRTLIN
  584.     LXI    D,ICLFLG
  585.     CALL    PRTLIN
  586.     LXI    D,LSTFLG
  587.     CALL    PRTLIN
  588.     LXI    D,MACFLG
  589.     CALL    PRTLIN
  590.     LXI    D,EOJMSG
  591. ;
  592. ;    Print message at DE and abort
  593. ;
  594. EREXIT:    PUSH    D
  595.     LXI    D,CRLFMG
  596.     CALL    PRTLIN
  597.     POP    D
  598.     CALL    PRTLIN
  599.     JMP    ABORT
  600. ;
  601. JABORT:    LXI    D,JABTMG
  602.     CALL    PRTLIN
  603.     JMP    GETLN7
  604. ;
  605. JABTMG    DB    CR,LF,'*** Job Cancelled ***',CR,LF,0
  606. ;
  607. UPSMSG    DB    0,LF,'The following operands'
  608.     DB    ' have been used in your '
  609.     DB    'source and have not'
  610.     DB    CR,LF
  611.     DB    'been fully translated.  You must '
  612.     DB    'complete the translation using an editor.'
  613.     DB    CR,LF,HT
  614.     DB    'original:',HT,HT
  615.     DB    'must be translated to:'
  616.     DB    CR,LF,0
  617. ENDIFL    DB    0,'IF or IFC',HT,HT,'%IF(exp)THEN(txt1)',CR,LF
  618.     DB    HT,'ELSE',HT,HT,HT,'ELSE(txt2)',CR,LF
  619.     DB    HT,'ENDIF or #ENDIF',HT,HT,'FI'
  620.     DB    CR,LF,0
  621. ICLFLG    DB    0,'ICL'
  622.     DB    CR,LF,0
  623. LSTFLG    DB    0,'LST or LIST'
  624.     DB    CR,LF,0
  625. MACFLG    DB    0,'MACRO or MAC',HT,HT,'%DEFINE(mname[(plist)])'
  626.     DB    CR,LF
  627.     DB    HT,'#macro-call',HT,HT,'%macro-call'
  628.     DB    CR,LF,0
  629. ;
  630. EOJMSG    DB    '*** End of Job ***',CR,LF,0
  631.  
  632. ;*******************************************************
  633. ;
  634. ;    Process line
  635. ;
  636. PROCLIN:
  637.     LXI    H,LBUFF
  638. PROCLN0:
  639.     CALL    FNDOPC
  640.     JNZ    PRCLN00
  641.     CALL    PTCOLN    ; Put out pending colon
  642.     JMP    PUTND6
  643. PRCLN00:
  644.     LDA    COLNFL    ; is there a colon
  645.     ORA    A    ;  to print ?
  646.     JZ    PRCLN02    ; No, put white space
  647.  
  648.     LXI    H,OPTPSD ; See if opcode
  649.     LXI    B,OPBFLN ;  is DB, DW, DS, or EQU
  650.     CALL    SCANOP
  651.     MVI    A,' '
  652.     JZ    PRCLN01     ; If so, put space
  653.     MVI    A,':'     ;  otherwise, put colon
  654.  
  655. PRCLN01:
  656.     CALL    PUTCHR
  657.  
  658. PRCLN02:
  659.     LHLD    xWHITE
  660.     CALL    PUTSPT
  661.  
  662. PROCLN1:
  663.     LXI    H,OPTIMM ;imm or one byte
  664.     LXI    B,2*OPBFLN
  665.     CALL    SCANOP
  666.     JZ    DOIMM
  667.  
  668.     LXI    H,OPTONE ; one byte opcodes
  669.     LXI    B,2*OPBFLN
  670.     CALL    SCANOP
  671.     JZ    DO$ONE
  672.  
  673.     LXI    H,OPTREG ;register
  674.     LXI    B,2*OPBFLN
  675.     CALL    SCANOP
  676.     JZ    DOREG
  677.  
  678.     LXI    H,OPTBDB ; db and equ
  679.     LXI    B,2*OPBFLN
  680.     CALL    SCANOP
  681.     JZ    DOSIMP
  682.  
  683.     LXI    H,OPTSMP ; simple
  684.     LXI    B,2*OPBFLN
  685.     CALL    SCANOP
  686.     JZ    DOSIMP
  687.  
  688.     LXI    H,OPTROT ; rotates
  689.     LXI    B,2*OPBFLN
  690.     CALL    SCANOP
  691.     JZ    DOROT
  692.  
  693.     LXI    H,OPTDCR ; dcr, inr
  694.     LXI    B,2*OPBFLN
  695.     CALL    SCANOP
  696.     JZ    DODCR
  697.  
  698.     LXI    H,OPTDCX ;16 bit dcx, inx
  699.     LXI    B,2*OPBFLN
  700.     CALL    SCANOP
  701.     JZ    DODCX
  702.  
  703.     LXI    H,OPTTDL ;tdl
  704.     LXI    B,OPBFLN
  705.     CALL    SCANOP
  706.     CZ    DOTDL
  707.  
  708.     LXI    H,OPTRCC ;ret cond
  709.     LXI    B,2*OPBFLN
  710.     CALL    SCANOP
  711.     JZ    DORET
  712.  
  713.     LXI    H,OPTCCC ;call cond
  714.     LXI    B,2*OPBFLN
  715.     CALL    SCANOP
  716.     JZ    DOCALL
  717.  
  718.     LXI    H,OPTJCC ;jump cond
  719.     LXI    B,2*OPBFLN
  720.     CALL    SCANOP
  721.     JZ    DOJMP
  722.  
  723.     LXI    H,OPTMSC ;index & misc
  724.     LXI    B,2*OPBFLN+2
  725.     CALL    SCANOP
  726.     JZ    EXEC
  727.  
  728. PUTCOD:    LHLD    xOPCOD    ;this fix prevents macro
  729.     JMP    PUTEND    ;names from being split
  730.  
  731. PUTOPR:    LHLD    xOPRND
  732.  
  733. PUTEND:    XRA    A
  734.     STA    LCFLAG
  735.     STA    LCDFLG
  736.  
  737.     MVI    C,N00    ;  putout w/o
  738. PUTND1:    MOV    A,M    ;  change
  739.  
  740.     CPI    ' '
  741.     JZ    PUTND3
  742.     CPI    HT
  743.     JZ    PUTND3
  744.  
  745.     CPI    CR
  746.     JZ    PUTLNC
  747.  
  748.     CPI    ';'
  749.     JZ    PUTND4
  750.  
  751.     CPI    EOS    ; process exclamation pt.
  752.     JZ    PTND21    ;  statement separator
  753.  
  754.     CPI    QUOTE
  755.     JNZ    PUTND2
  756.     DCR    C
  757.     JZ    PUTND2
  758.     MVI    C,N01
  759. PUTND2:    CALL    PUTCHR
  760.     INX    H
  761.     JMP    PUTND1
  762.  
  763. ;
  764. PTND21:    CALL    SKSPHT
  765.     INX    H    ; Inc past excl. pt.
  766. PTND22:    MOV    A,M
  767.     CPI    ';'
  768.     JZ    PUTND5
  769.  
  770.     LDA    MLTLFL    ; Put out as separate
  771.     ORA    A    ;  lines
  772.     JZ    PTND24    ; NO
  773. ;
  774.     MOV    A,M
  775.     CPI    ' '    ; Change space to HT
  776.     JNZ    PTND23
  777.     MVI    M,HT
  778. PTND23:    CALL    PCRLF
  779.     JMP    PROCLN0
  780. ;
  781. PTND24:    LDA    TEMP    ; Was last character put
  782.     CPI    ' '    ;  out a space ?
  783.     JZ    PTND25
  784.     CPI    HT    ;  or a TAB ?
  785.     JZ    PTND25
  786.     MVI    A,' '    ; NO, put out a space
  787.     CALL    PUTCHR
  788. PTND25:    MVI    A,'!'
  789.     CALL    PUTCHR
  790.     JMP    PROCLN0
  791. ;
  792. ;
  793. PUTND3:    PUSH    H    ;Space or Tab come here
  794.     CALL    SKSPHT
  795.  
  796.     CPI    CR    ;this fix filters out
  797.     JZ    PUTLNB    ;trailing spaces or tabs
  798.     POP    H
  799.  
  800.     CPI    EOS    ; fix to process excl. pt.
  801.     JZ    PTND21
  802.  
  803.     CPI    ';'
  804.     MOV    A,M    ;prevent blank being replaced
  805.             ;by ';' in string data
  806.     JZ    PUTND4
  807.     CALL    PUTSPT
  808.     JMP    PUTND1
  809. ;
  810. PUTND4:    DCR    C    ;';' come here
  811.     INR    C
  812.     JNZ    PUTND2
  813.     CALL    SKSPHT
  814.  
  815. ; Tab comments to proper column
  816.  
  817. PUTND5:    MVI    B,41
  818. PTND51:    LDA    COLNUM
  819.     CMP    B    ;colnum>=41?
  820.     JNC    PTND54
  821.     DCR    A    ;no, insert
  822.     ANI    NF8    ;tabs to
  823.     ADI    N09    ;start output
  824.     CMP    B    ;at col. 33
  825.     JZ    PTND54
  826.     JC    PTND52
  827.     MVI    A,' '
  828.     JMP    PTND53
  829. ;
  830. PTND52:    MVI    A,HT
  831. PTND53:    CALL    PUTCHR
  832.     JMP    PTND51
  833.  
  834. PTND54:    LDA    TEMP    ; insure
  835.     CPI    ' '    ; space
  836.     JZ    PUTND6    ; before
  837.     CPI    HT    ; semi-colon
  838.     JZ    PUTND6    ;
  839.     MVI    A,' '    ;
  840.     CALL    PUTCHR    ;
  841. PUTND6:    MOV    A,M
  842.     INX    H
  843.     CPI    EOS
  844.     JZ    PTND22
  845.     ORA    A
  846.     RZ
  847.     CALL    PUTCHR
  848.     JMP    PUTND6
  849.  
  850. ;
  851. ;    Put line at HL to output file until 0
  852. ;    and reset colnum to 1.
  853. ;
  854. PUTLNB:    XTHL        ;filter trailing
  855.     POP    H    ;blanks or tabs
  856.  
  857. PUTLNC:    JMP    PUTLIN
  858.  
  859. ;*******************************************************
  860. ;
  861. ;    Process labels, find potential opcode.
  862. ;
  863. FNDOPC:    XRA    A
  864.     STA    COLNFL    ; Reset colon flag
  865.  
  866.     MOV    A,M
  867.     CPI    ' '
  868.     JZ    FNDOP3
  869.     CPI    HT
  870.     JZ    FNDOP3
  871.  
  872.     CPI    CR    ;pass blank
  873.     RZ        ;lines
  874.     CPI    EOS    ; excl. pt. separator
  875.     RZ
  876.  
  877.     CPI    ';'
  878.     RZ
  879.  
  880.     CPI    '*'    ; asterisk in first column
  881.     JNZ    FNDOP1    ; is a comment line
  882.     MVI    M,';'
  883.     RET
  884. ;
  885. ; Only comes here if this is a label
  886. ;
  887. FNDOP1:    MVI    C,N00
  888.     MVI    A,':'    ; Set colon flag
  889.     STA    COLNFL    ;  to insure colon after label
  890.  
  891. FNDOP2:    MOV    A,M
  892.  
  893.     CPI    ':'
  894.     JZ    FNDOP4
  895.  
  896.     CPI    HT
  897.     JZ    FNDOP6
  898.     CPI    ' '
  899.     JZ    FNDOP6
  900.  
  901.     CPI    CR
  902.     RZ
  903.     CPI    EOS
  904.     RZ
  905.  
  906.     CPI    ';'
  907.     JZ    FNDP72
  908.  
  909.     CALL    PUTCHR
  910.     INX    H
  911.     INR    C
  912.     JMP    FNDOP2
  913.  
  914. ; Comes here only if space or tab at beginning
  915. ; of line.
  916.  
  917. FNDOP3:
  918.     PUSH    H
  919.     CALL    SKSPHT    ;find first non-sp or tab
  920.     CPI    CR
  921.     JZ    FNDOP9
  922.     CPI    EOS
  923.     JZ    FNDOP9
  924.     CPI    ';'
  925.     JZ    FNDP71
  926.     POP    H
  927.  
  928.     CALL    PUTSPT    ;print until non-sp or ht
  929.     PUSH    H
  930.     CALL    FINDLM    ;find ,:+-/*); CR HT or SP at HL
  931.     CPI    ':'
  932.     POP    H
  933.     JZ    FNDOP1
  934.     JMP    FNDOP7
  935. ;
  936. ; Colon terminating label comes here
  937. ;
  938. FNDOP4:    INX    H
  939.     MOV    A,M
  940.     CPI    ':'
  941.     JNZ    FNDOP5
  942.     CALL    PUTCHR
  943.     INX    H
  944. FNDOP5:    MVI    A,':'
  945.     STA    COLNFL    ; Set colon flag
  946. ;
  947. ; HT or SP comes here
  948. ;
  949. FNDOP6:
  950. ;
  951. ; See if there is an opcode field
  952. ;
  953. FNDOP7:    PUSH    H
  954.  
  955.     CALL    SKSPHT
  956.     MOV    A,M
  957.  
  958.     CPI    CR
  959.     JZ    FNDOP9    ; filter trailing SP or TAB
  960.     CPI    EOS
  961.     JZ    FNDOP9    ; excl. pt. separator
  962.  
  963.     CPI    ';'
  964.     JNZ    FNDOP8
  965.  
  966. FNDP71:    XTHL
  967.     POP    H
  968. FNDP72:    POP    B    ; clear return
  969.     CALL    PTCOLN    ; Put colon out if flag set
  970.     JMP    PUTND5    ; tab to proper column
  971. ;
  972. ; Have located opcode field
  973. ;
  974. FNDOP8:    POP    H
  975.     SHLD    xWHITE
  976.     CALL    SKSPHT
  977.  
  978. ;    Move potential opcode to OPCBUF
  979.  
  980. MOVOPC:    SHLD    xOPCOD
  981.     MVI    B,OPBFLN
  982.     LXI    D,OPCBUF
  983.     CALL    MOVBDH    ; move up to B char from HL to
  984.     CALL    SKSPHT    ; DE until ,:+-/*); CR HT SP
  985.     SHLD    xOPRND
  986.     SUB    A
  987.     INR    A
  988.     RET
  989.  
  990. ; come here on CR to filter trailing SP or TAB
  991.  
  992. FNDOP9:    CALL    PTCOLN    ; Put out colon if flag set
  993.     XTHL
  994.     POP    H
  995.     XRA    A
  996.     RET
  997.  
  998. ;
  999. ;    Put colon to output file if colon
  1000. ;    flag is set.
  1001. ;
  1002. PTCOLN:    LDA    COLNFL
  1003.     ORA    A
  1004.     RZ
  1005.  
  1006.     CALL    PUTCHR
  1007.     XRA    A
  1008.     STA    COLNFL
  1009.     RET
  1010. ;
  1011. COLNFL    DB    0
  1012. xWHITE    DW    0    ; pointer to white space after
  1013.             ;  label and before opcode
  1014.  
  1015. ;*******************************************************
  1016. ;
  1017. ;    Opcode tables
  1018. ;
  1019. OPTIMM    DB    'ACI  ADC  '
  1020.     DB    'ADI  ADD  '
  1021.     DB    'ANI  AND  '
  1022.     DB    'CPI  CMP  '
  1023.     DB    'ORI  OR   '
  1024.     DB    'SBI  SBB  '
  1025.     DB    'SUI  SUB  '
  1026.     DB    'XRI  XOR  '
  1027.     DB    0
  1028.  
  1029. OPTONE    DB    'RET  RET  '
  1030.     DB    'CMC  CMC  '
  1031.     DB    'HLT  HLT  '
  1032.     DB    'STC  STC  '
  1033.     DB    'DAA  DAA  '
  1034.     DB    'DI   CLI  '
  1035.     DB    'EI   STI  '
  1036.     DB    'NOP  NOP  '
  1037.     DB    0
  1038.  
  1039. OPTREG    DB    'ADC  ADC  '
  1040.     DB    'ADD  ADD  '
  1041.     DB    'ANA  AND  '
  1042.     DB    'CMP  CMP  '
  1043.     DB    'ORA  OR   '
  1044.     DB    'SBB  SBB  '
  1045.     DB    'SUB  SUB  '
  1046.     DB    'XRA  XOR  '
  1047.     DB    0
  1048.  
  1049. OPTPSD    DB    'DB   '
  1050.     DB    'EQU  '
  1051.     DB    'DW   '
  1052.     DB    'DS   '
  1053.     DB    0
  1054.  
  1055. OPTBDB    DB    'DB   DB   '
  1056.     DB    'EQU  EQU  '
  1057.     DB    0
  1058.  
  1059. OPTSMP    DB    'JMP  JMP  '
  1060.     DB    'CALL CALL '
  1061.     DB    'DS   RS   '
  1062.     DB    'DW   DW   '
  1063.     DB    'SET  EQU  '
  1064. OPTENT    DB    'ENT  ENTRY'
  1065.     DB    'NAM  NAME '
  1066.     DB    'RAM  DATA '
  1067.     DB    'ROG  REL  '
  1068.     DB    0
  1069.  
  1070. OPTDCR    DB    'DCR  DEC  '
  1071.     DB    'INR  INC  '
  1072.     DB    0
  1073.  
  1074. OPTROT    DB    'RAL  RCL  '
  1075.     DB    'RAR  RCR  '
  1076.     DB    'RLC  ROL  '
  1077.     DB    'RRC  ROR  '
  1078.     DB    0
  1079.  
  1080. OPTDCX    DB    'DCX  DEC  '
  1081.     DB    'INX  INC  '
  1082.     DB    0
  1083.  
  1084. OPTTDL    DB    'REQ  '
  1085.     DB    'RNE  '
  1086.     DB    'RLT  '
  1087.     DB    'RGE  '
  1088.     DB    'CEQ  '
  1089.     DB    'CNE  '
  1090.     DB    'CLT  '
  1091.     DB    'CGE  '
  1092.     DB    'JEQ  '
  1093.     DB    'JNE  '
  1094.     DB    'JLT  '
  1095.     DB    'JGE  '
  1096.     DB    0
  1097.  
  1098. OPTRCC    DB    'RC   JNC  '
  1099.     DB    'RNC  JC   '
  1100.     DB    'RZ   JNZ  '
  1101.     DB    'RNZ  JZ   '
  1102.     DB    'RP   JS   '
  1103.     DB    'RM   JNS  '
  1104.     DB    'RPE  JPO  '
  1105.     DB    'RPO  JPE  '
  1106.     DB    0
  1107.  
  1108. OPTCCC    DB    'CC   JNC  '
  1109.     DB    'CNC  JC   '
  1110.     DB    'CZ   JNZ  '
  1111.     DB    'CNZ  JZ   '
  1112.     DB    'CP   JS   '
  1113.     DB    'CM   JNS  '
  1114.     DB    'CPE  JPO  '
  1115.     DB    'CPO  JPE  '
  1116.     DB    0
  1117.  
  1118. OPTJCC    DB    'JC   JNC  '
  1119.     DB    'JNC  JC   '
  1120.     DB    'JZ   JNZ  '
  1121.     DB    'JNZ  JZ   '
  1122.     DB    'JP   JS   '
  1123.     DB    'JM   JNS  '
  1124.     DB    'JPE  JPO  '
  1125.     DB    'JPO  JPE  '
  1126.     DB    0
  1127.  
  1128. OPTMSC    DB    'LXI  MOV  '
  1129.     DW    DOLXI
  1130.     DB    'POP  POP  '
  1131.     DW    DOPOP
  1132.     DB    'PUSH PUSH '
  1133.     DW    DOPSH
  1134.     DB    'DAD  ADD  '
  1135.     DW    DODAD
  1136.     DB    'LDA  MOV  '
  1137.     DW    DOLDA
  1138.     DB    'LDAX MOV  '
  1139.     DW    DOLDAX
  1140.     DB    'LHLD MOV  '
  1141.     DW    DOLHLD
  1142.     DB    'MOV  MOV  '
  1143.     DW    DOMOV
  1144.     DB    'MVI  MOV  '
  1145.     DW    DOMVI
  1146.     DB    'IN   IN   '
  1147.     DW    DOIN
  1148.     DB    'OUT  OUT  '
  1149.     DW    DOOUT
  1150.     DB    'PCHL JMP  '
  1151.     DW    DOPCHL
  1152.     DB    'RST  CALL '
  1153.     DW    DORST
  1154.     DB    'SHLD MOV  '
  1155.     DW    DOSHLD
  1156.     DB    'SPHL MOV  '
  1157.     DW    DOSPHL
  1158.     DB    'STA  MOV  '
  1159.     DW    DOSTA
  1160.     DB    'STAX MOV  '
  1161.     DW    DOSTAX
  1162.     DB    'XCHG XCHG '
  1163.     DW    DOXCHG
  1164.     DB    'XTHL XCHG '
  1165.     DW    DOXTHL
  1166.     DB    'CMA  NOT  '
  1167.     DW    DOCMA
  1168.     DB    'IF   IF   '
  1169.     DW    DOIFC
  1170.     DB    'LIST LIST '
  1171.     DW    DOLST
  1172.     DB    'MACROMACRO'
  1173.     DW    DOMAC
  1174. OPTIFC    DB    'IFC  IF   '
  1175.     DW    DOIFC
  1176.     DB    'ICL  *INCL'
  1177.     DW    DOICL
  1178.     DB    'LST  LIST '
  1179.     DW    DOLST
  1180.     DB    'MAC  MACRO'
  1181.     DW    DOMAC
  1182.     DB    0
  1183.  
  1184. ;*******************************************************
  1185. ;
  1186. ;    Scan table at HL for match to OPBFLN
  1187. ;    char string at OPCBUF.
  1188. ;    Ret Z and HL-> entry if match.
  1189. ;
  1190. SCANOP:    MOV    A,M
  1191.     ANA    A
  1192.     JZ    SCNOP1
  1193.     PUSH    B
  1194.     MVI    B,OPBFLN
  1195.     LXI    D,OPCBUF
  1196.     CALL    CBDEHL    ;comp B bytes (DE)-(HL)
  1197.     POP    B
  1198.     RZ
  1199.     DAD    B
  1200.     JMP    SCANOP
  1201. ;
  1202. SCNOP1:    INR    A
  1203.     RET
  1204.  
  1205. ;
  1206. ;    Gets routine address  from
  1207. ;    HL+2*OPBFLN and jumps to routine.
  1208. ;
  1209. EXEC:    PUSH    H
  1210.     LXI    B,2*OPBFLN
  1211.     DAD    B
  1212.     MOV    C,M
  1213.     INX    H
  1214.     MOV    B,M
  1215.     POP    H
  1216.     PUSH    B    ;address on stack
  1217.     RET        ;go to it
  1218.  
  1219. ;
  1220. ;    Put up to OPBFLN char at HL+OPBFLN
  1221. ;    to output file.  Stop at space,
  1222. ;    and put tab to output file.
  1223. ;
  1224. PUTOPHT:
  1225.     CALL    PUTOPC
  1226. PUTHT:    MVI    A,HT
  1227.     JMP    PUTCHR
  1228.  
  1229. ;
  1230. ;    Put space or tab (contents of MLTSPC)
  1231. ;    to output file as separator after opcode
  1232. ;    in multi-statement output line.
  1233. ;
  1234. PUTHTS:    LDA    MLTSPC
  1235.     JMP    PUTCHR
  1236. ;
  1237. MLTSPC    DB    HT
  1238.  
  1239. ;
  1240. ;
  1241. ;
  1242. PUTOPC:    LXI    B,OPBFLN
  1243.     DAD    B    ; HL -> new opcode
  1244.     MOV    B,C
  1245. PUTOP1:    MOV    A,M
  1246.  
  1247.     CPI    ' '
  1248.     RZ
  1249.  
  1250.     CPI    HT
  1251.     RZ
  1252.  
  1253.     LDA    LCFLAG
  1254.     ORA    A
  1255.     MOV    A,M
  1256.     JZ    PUTOP2
  1257.     ORI    20H
  1258. PUTOP2:
  1259.     CALL    PUTCHR
  1260.     INX    H
  1261.     DCR    B
  1262.     JNZ    PUTOP1
  1263.  
  1264.     RET
  1265.  
  1266. ;
  1267. ;    Put string at HL to output file until 0.
  1268. ;    If (LCFLAG) set, convert to lower case.
  1269. ;
  1270. PUTOPS:    MOV    A,M
  1271.     ORA    A
  1272.     RZ
  1273.     LDA    LCFLAG
  1274.     ORA    A
  1275.     MOV    A,M
  1276.     JZ    PUTOS0
  1277.     CALL    LCASE
  1278. PUTOS0:    CALL    PUTCHR
  1279.     INX    H
  1280.     JMP    PUTOPS
  1281.  
  1282. ;
  1283. ;    Put string at HL to output file until 0.
  1284. ;    If (LCDFLG) set, convert to lower case.
  1285. ;
  1286. PUTRND:    MOV    A,M
  1287.     ORA    A
  1288.     RZ
  1289.     LDA    LCDFLG
  1290.     ORA    A
  1291.     MOV    A,M
  1292.     JZ    PUTRN0
  1293.     CALL    LCASE
  1294. PUTRN0:    CALL    PUTCHR
  1295.     INX    H
  1296.     JMP    PUTRND
  1297. ;
  1298. LCDFLG    DB    0
  1299.  
  1300. ;
  1301. ;    Find first ,:+-/*); CR HT or SP at HL,
  1302. ;    return A = (HL).
  1303. ;
  1304. FINDLM:    PUSH    B
  1305.     CALL    CHKDLM
  1306.     POP    B
  1307.     RZ
  1308.     INX    H
  1309.     JMP    FINDLM
  1310. ;
  1311. ;    Fill B locations at DE with spaces.
  1312. ;    Move up to B char from HL to DE until
  1313. ;    ,:+-/*); CR HT or SP encountered.
  1314. ;    Return Z and HL->special char if found.
  1315. ;    (search B+1 loc for special char.)
  1316. ;
  1317. MOVBDH:    MOV    C,B
  1318.     MVI    B,N00
  1319.     PUSH    B
  1320.     PUSH    D
  1321.     PUSH    H    ; fill BC locations
  1322.     CALL    FILLBD    ; at DE with spaces
  1323.     POP    H    ;
  1324.     POP    D
  1325.     POP    B
  1326. MOVBD1:    PUSH    B    ; ret Z, A=(HL)
  1327.     CALL    CHKDLM    ; if (HL) is
  1328.     POP    B    ; ,:+-/*); CR HT or SP
  1329.     RZ
  1330.  
  1331.     MOV    A,M
  1332.     STAX    D
  1333.     INX    D
  1334.     INX    H
  1335.     DCX    B
  1336.     MOV    A,B
  1337.     ORA    C
  1338.     JZ    CHKDLM
  1339.     JMP    MOVBD1
  1340.  
  1341. ;
  1342. ;    Skip spaces and tabs.
  1343. ;    Return HL -> non-space or non-tab
  1344. ;
  1345. SKSPHT:    MOV    A,M
  1346.     CPI    ' '
  1347.     JZ    SKSPT1
  1348.     CPI    HT
  1349.     RNZ
  1350. SKSPT1:    INX    H
  1351.     JMP    SKSPHT
  1352.  
  1353. ;
  1354. ;    Ret Z, A=(HL) if
  1355. ;    HL is ,:+-/*); CR HT SP or EOS
  1356. ;
  1357. CHKDLM:    MOV    A,M
  1358.     CPI    HT
  1359.     RZ
  1360.     CPI    ' '
  1361.     RZ
  1362.     CPI    ','
  1363.     RZ
  1364.     CPI    ';'
  1365.     RZ
  1366.     CPI    CR
  1367.     RZ
  1368.     CPI    ':'
  1369.     RZ
  1370.     CPI    '+'
  1371.     RZ
  1372.     CPI    '-'
  1373.     RZ
  1374.     CPI    '/'
  1375.     RZ
  1376.     CPI    '*'
  1377.     RZ
  1378.     CPI    ')'
  1379.     RZ
  1380.     CPI    EOS
  1381.     RET
  1382. ;
  1383. ;    Compares B chars at DE with chars
  1384. ;    at HL.
  1385. ;    Ret Z if match.
  1386. ;    Preserve HL, DE, BC
  1387. ;
  1388. CBDEHL:    PUSH    H
  1389.     PUSH    D
  1390.     PUSH    B
  1391. CBDH1:    LDAX    D
  1392.  
  1393.     CPI    'a'
  1394.     JC    CBDH2
  1395.     STA    LCFLAG
  1396.     ANI    05FH
  1397. CBDH2:
  1398.     CMP    M
  1399.     JNZ    CBDH3
  1400.     INX    H
  1401.     INX    D
  1402.     DCR    B
  1403.     JNZ    CBDH1
  1404. CBDH3:    POP    B
  1405.     POP    D
  1406.     POP    H
  1407.     RET
  1408.  
  1409. LCFLAG    DB    0
  1410.  
  1411. ;
  1412. ;    Fill BC locations starting at
  1413. ;    DE with spaces.
  1414. ;    Returns A = space, DE -> next free
  1415. ;    location, HL = DE - 1, BC = 0.
  1416. ;
  1417. FILLBD:    MVI    A,' '
  1418.     STAX    D
  1419.     MOV    H,D
  1420.     MOV    L,E
  1421.     INX    D
  1422.     DCX    B
  1423.     CALL    MOVIR
  1424.     RET
  1425.  
  1426. ;
  1427. ;    Subtract DE from HL, result in HL.
  1428. ;
  1429. SBCHLDE:
  1430.     MOV    A,L
  1431.     SUB    E
  1432.     MOV    L,A
  1433.     MOV    A,H
  1434.     SBB    D
  1435.     MOV    H,A
  1436.     RET
  1437.  
  1438. ;
  1439. ;    (DE)=(HL), INC HL, INC DE, DEC BC
  1440. ;    Repeat until BC = 0.
  1441. ;
  1442. MOVIR:    MOV    A,M
  1443.     STAX    D
  1444.     INX    H
  1445.     INX    D
  1446.     DCX    B
  1447.     MOV    A,B
  1448.     ORA    C
  1449.     JNZ    MOVIR
  1450.     RET
  1451.  
  1452. ;*******************************************************
  1453. ;
  1454. ;    Translation Routines
  1455. ;
  1456. ;*******************************************************
  1457.  
  1458. ;
  1459. ;    Immediate
  1460. ;    e.g., CPI n -> CMP AL,n
  1461. ;
  1462. DOIMM:    CALL    PUTOPHT
  1463.     LXI    H,OPALC
  1464.     CALL    PUTOPS
  1465.     JMP    PUTOPR
  1466. ;
  1467. OPALC    DB    'AL,',0
  1468.  
  1469. ;
  1470. ;    One byte (implied)
  1471. ;    e.g., DI -> CLI
  1472. ;
  1473. DO$ONE:    CALL    PUTOPC
  1474.     JMP    PUTOPR
  1475.  
  1476. ;
  1477. ; Simple translation
  1478. ; e.g., DS n -> RS n
  1479. ;
  1480. DOSIMP:    CALL    PUTOPHT
  1481.     JMP    PUTOPR
  1482.  
  1483. ;
  1484. ;    Register instructions,
  1485. ;    e.g., XRA r -> XOR AL,r'
  1486. ;
  1487. DOREG:    CALL    PUTOPHT    ; Put out opcode+tab
  1488.     LXI    H,OPALC    ; Put out 'AL,'
  1489.     CALL    PUTOPS
  1490.     LHLD    xOPRND
  1491.     CALL    TRNRG    ; Translate register
  1492.     JNZ    PUTEND
  1493.     XCHG        ; Get HL -> r'
  1494.     CALL    PUTRND
  1495.     XCHG
  1496.     JMP    PUTEND
  1497.  
  1498. ;
  1499. ;    MOV r,s -> MOV r',s'
  1500. ;
  1501. DOMOV:    CALL    PUTOPHT
  1502.  
  1503.     LHLD    xOPRND
  1504.     CALL    TRNRG
  1505.     JNZ    PUTOPR
  1506.  
  1507.     XCHG
  1508.     CALL    PUTRND
  1509.     XCHG
  1510.  
  1511.     XRA    A
  1512.     STA    LCDFLG    ; Clear lower case flag
  1513.     MOV    A,M    ; Get comma
  1514.     INX    H    ; Inc past ','
  1515.     CALL    PUTCHR
  1516.  
  1517.     CALL    TRNRG
  1518.     JNZ    PUTEND
  1519.  
  1520.     XCHG
  1521.     CALL    PUTRND
  1522.     XCHG
  1523.     JMP    PUTEND
  1524.  
  1525. ;
  1526. ; Dec and Inc byte register
  1527. ;    DCR r -> DEC r'
  1528. ;
  1529. DODCR:
  1530.  
  1531. ;
  1532. ;    MVI r,n -> MOV r',n
  1533. ;
  1534. DOMVI:    CALL    PUTOPHT
  1535.  
  1536.     LHLD    xOPRND
  1537.     CALL    TRNRG
  1538.     JNZ    PUTEND
  1539.  
  1540.     LDAX    D
  1541.     CPI    '['
  1542.     JNZ    DOMVI1
  1543.  
  1544.     PUSH    H
  1545.     LXI    H,OPBYTP
  1546.     CALL    PUTLIN
  1547.     POP    H
  1548.  
  1549. DOMVI1:    XCHG
  1550.     CALL    PUTRND
  1551.     XCHG
  1552.     JMP    PUTEND
  1553. ;
  1554. OPBYTP    DB    'BYTE PTR ',0
  1555.  
  1556. ;
  1557. ; Translate 8080 byte registers to
  1558. ; 8086 byte registers.
  1559. ; Enter with HL -> to 8080 register.
  1560. ; If match,
  1561. ;  return Z set, HL -> next, DE -> translation,
  1562. ; Otherwise,
  1563. ;  return NZ, HL, DE unchanged.
  1564. ;
  1565. TRNRG:    MOV    A,M
  1566.     CPI    'a'
  1567.     JC    TRNRG2
  1568.     STA    LCDFLG
  1569. TRNRG2:    ANI    5FH
  1570.     PUSH    H
  1571.     LXI    H,RTBL
  1572.     MVI    B,RTBLE-RTBL
  1573. TRNRG3:    CMP    M
  1574.     JZ    TRNRG4
  1575.     INX    H
  1576.     DCR    B
  1577.     JNZ    TRNRG3
  1578.     POP    H    ; HL -> r
  1579.     MVI    A,0FFH    ; return NZ
  1580.     ORA    A    ; if no match
  1581.     RET
  1582. ;
  1583. TRNRG4:    LXI    D,RTBL
  1584.     CALL    SBCHLDE
  1585.     DAD    H
  1586.     LXI    D,RPTBL
  1587.     DAD    D
  1588.     MOV    E,M
  1589.     INX    H
  1590.     MOV    D,M
  1591.     POP    H
  1592.     INX    H    ; point to next
  1593.     XRA    A    ; return Z
  1594.     RET
  1595. ;
  1596. RTBL    DB    'ABCDEHLM'
  1597. RTBLE:
  1598. RPTBL    DW    ALREG
  1599.     DW    CHREG
  1600.     DW    CLREG
  1601.     DW    DHREG
  1602.     DW    DLREG
  1603.     DW    BHREG
  1604.     DW    BLREG
  1605.     DW    PBX
  1606. ;
  1607. ALREG    DB    'AL',0
  1608. CHREG    DB    'CH',0
  1609. CLREG    DB    'CL',0
  1610. DHREG    DB    'DH',0
  1611. DLREG    DB    'DL',0
  1612. BHREG    DB    'BH',0
  1613. BLREG    DB    'BL',0
  1614. PBX    DB    '[BX]',0
  1615.  
  1616. ;
  1617. ; Rotates
  1618. ;
  1619. DOROT:    CALL    PUTOPHT
  1620.     LXI    H,OPALC    ; 'AL,'
  1621.     CALL    PUTOPS
  1622.     MVI    A,'1'
  1623.     CALL    PUTCHR
  1624.     JMP    PUTOPR
  1625.  
  1626. ;
  1627. ;    DAD rp -> ADD BX,rp'
  1628. ;
  1629. DODAD:    LDA    DADFL
  1630.     ORA    A
  1631.     JZ    DODAD1
  1632.  
  1633.     PUSH    H
  1634.     LXI    H,OPPSHF ;'PUSHF'
  1635.     CALL    PUTOPS
  1636.     CALL    SEP     ; separator
  1637.     POP    H
  1638.  
  1639.     CALL    PUTOPC
  1640.     CALL    PUTHTS    ; Put out space or tab
  1641.     JMP    DODAD2
  1642.  
  1643. DODAD1:    CALL    PUTOPHT
  1644.  
  1645. DODAD2:    LXI    H,OPBXC    ;'BX,'
  1646.     CALL    PUTOPS
  1647.  
  1648.     LHLD    xOPRND
  1649.     CALL    TRNRP    ; DE -> translated rp
  1650.     JNZ    PUTOPR
  1651.     LDAX    D
  1652.     CPI    'A'
  1653.     JZ    PUTOPR
  1654.  
  1655.     XCHG        ; HL -> translated rp
  1656.     CALL    PUTRND
  1657.     XCHG        ; HL -> next
  1658.  
  1659.     LDA    DADFL
  1660.     ORA    A
  1661.     JZ    PUTEND
  1662.  
  1663.     PUSH    H
  1664.     CALL    SEP     ; Separator
  1665.     LXI    H,OPPOPF ; 'POPF'
  1666.     CALL    PUTOPS
  1667.     POP    H
  1668.  
  1669.     JMP    PUTEND
  1670. ;
  1671. OPBXC    DB    'BX,',0
  1672.  
  1673. ;
  1674. ;    DCX or INX rp -> DEC or INC rp'
  1675. ;
  1676. DODCX:    LDA    INXFL    ; If set, output
  1677.     ORA    A    ;  PUSHF to preserve
  1678.     JZ    DODCX1    ;  flags
  1679.  
  1680.     PUSH    H
  1681.     LXI    H,OPPSHF ;'PUSHF'
  1682.     CALL    PUTOPS
  1683.     CALL    SEP     ; separator
  1684.     POP    H
  1685.  
  1686.     CALL    PUTOPC
  1687.     CALL    PUTHTS    ; Put out space or tab
  1688.     JMP    DODCX2
  1689.  
  1690. DODCX1:    CALL    PUTOPHT
  1691.  
  1692. DODCX2:    LHLD    xOPRND
  1693.     CALL    TRNRP    ; DE -> translated rp
  1694.     JNZ    PUTOPR
  1695.     LDAX    D
  1696.     CPI    'A'
  1697.     JZ    PUTOPR
  1698.  
  1699.     XCHG        ; HL -> translated rp
  1700.     CALL    PUTRND
  1701.     XCHG        ; HL -> next
  1702.  
  1703.     LDA    INXFL    ; If set, output
  1704.     ORA    A    ;  POPF to preserve
  1705.     JZ    PUTEND    ;  flags
  1706.  
  1707.     PUSH    H
  1708.     CALL    SEP     ; Separator
  1709.     LXI    H,OPPOPF ; 'POPF'
  1710.     CALL    PUTOPS
  1711.     POP    H
  1712.  
  1713.     JMP    PUTEND
  1714. ;
  1715. OPPSHF    DB    'PUSHF',0
  1716. OPPOPF    DB    'POPF',0
  1717.  
  1718. ;
  1719. ; PUSH rp -> PUSH rp'
  1720. ;
  1721. DOPSH:    XCHG
  1722.     LHLD    xOPRND
  1723.     MOV    A,M
  1724.     ANI    5FH
  1725.     CPI    'P'
  1726.     XCHG
  1727.     JNZ    DOPSH1
  1728.     XCHG
  1729.     CALL    TRNRP    ; DE -> trans, HL -> next
  1730.     JNZ    PUTCOD
  1731.     PUSH    H
  1732.     LXI    H,OPLAHF
  1733.     CALL    PUTRND
  1734.  
  1735.     LDA    PSWFL    ; Preserve order of
  1736.     ORA    A    ;  registers on stack ?
  1737.     CNZ    XAHAL    ; Yes,  XCHG AH,AL
  1738.  
  1739.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  1740.     LXI    H,OPPUSH
  1741.     CALL    PUTOPS
  1742.     CALL    PUTHTS
  1743.     POP    H
  1744.     XCHG        ; HL -> translated rp
  1745.     CALL    PUTRND
  1746.     XCHG        ; HL -> next
  1747.  
  1748.     LDA    PSWFL
  1749.     ORA    A
  1750.     CNZ    XAHAL
  1751.  
  1752.     JMP    PUTEND
  1753. ;
  1754. DOPSH1:    CALL    PUTOPHT
  1755. DOPSH2:    LHLD    xOPRND
  1756.     CALL    TRNRP    ; DE -> translated rp
  1757.     JNZ    PUTOPR
  1758. DOPSH3:    XCHG        ; HL -> translated rp
  1759.     CALL    PUTRND
  1760.     XCHG        ; HL -> next
  1761.     JMP    PUTEND
  1762. ;
  1763. OPLAHF    DB    'LAHF',0
  1764. OPPUSH    DB    'PUSH',0
  1765.  
  1766. ;
  1767. XAHAL:    PUSH    H
  1768.     CALL    SEP
  1769.     LXI    H,OPXCHG
  1770.     CALL    PUTRND
  1771.     CALL    PUTHTS
  1772.     LXI    H,OPAHAL
  1773.     CALL    PUTRND
  1774.     POP    H
  1775.     RET
  1776. ;
  1777. OPXCHG    DB    'XCHG',0
  1778. OPAHAL    DB    'AH,AL',0
  1779.  
  1780. ;
  1781. ; POP rp -> POP rp'
  1782. ;
  1783. DOPOP:    XCHG
  1784.     LHLD    xOPRND
  1785.     MOV    A,M
  1786.     ANI    5FH
  1787.     CPI    'P'
  1788.     XCHG
  1789.     JNZ    DOPSH1
  1790.  
  1791.     CALL    PUTOPC
  1792.     CALL    PUTHT    ; Put out space or tab
  1793.  
  1794.     LHLD    xOPRND
  1795.     CALL    TRNRP    ; DE -> trans, HL -> next
  1796.     JNZ    PUTOPR
  1797.  
  1798.     XCHG
  1799.     CALL    PUTRND
  1800.  
  1801.     LDA    PSWFL
  1802.     ORA    A
  1803.     CNZ    XAHAL
  1804.  
  1805.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  1806.     LXI    H,OPSAHF
  1807.     CALL    PUTRND
  1808.     XCHG
  1809.     JMP    PUTEND
  1810. ;
  1811. OPSAHF    DB    'SAHF',0
  1812.  
  1813. ;
  1814. ; LXI rp,nn -> MOV rp',OFFSET nn
  1815. ;
  1816. DOLXI:    CALL    PUTOPHT
  1817.     LHLD    xOPRND
  1818.     CALL    TRNRP
  1819.     JNZ    PUTOPR
  1820.     LDAX    D
  1821.     CPI    'A'
  1822.     JZ    PUTOPR
  1823.     XCHG
  1824.     CALL    PUTRND
  1825.     LXI    H,OFFATR
  1826.     CALL    PUTLIN
  1827.     XCHG        ; HL -> next
  1828.     INX    H    ; skip comma
  1829.     JMP    PUTEND
  1830. ;
  1831. OFFATR    DB    ',OFFSET ',0
  1832.  
  1833. ;
  1834. ; Translate 16 bit registers.
  1835. ; Enter with HL -> rp.
  1836. ; Returns HL -> next char, DE -> translation,
  1837. ; Z set if match,
  1838. ; otherwise, HL unchanged, NZ.
  1839. ;
  1840. TRNRP:    XRA    A
  1841.     STA    LCDFLG
  1842.     MOV    A,M
  1843.     CPI    'a'
  1844.     JC    TRNRP1
  1845.     STA    LCDFLG
  1846. TRNRP1:    ANI    5FH
  1847.     CPI    'B'
  1848.     JZ    TRNRPB
  1849.     CPI    'D'
  1850.     JZ    TRNRPD
  1851.     CPI    'H'
  1852.     JZ    TRNRPH
  1853.     CPI    'P'
  1854.     JZ    TRNRPP
  1855.     CPI    'S'
  1856.     JZ    TRNRPS
  1857. TRNRP2:    MVI    A,0
  1858.     STA    LCDFLG
  1859.     RET
  1860.  
  1861. ;
  1862. TRNRPB:    LXI    D,OPRCX    ;'CX'
  1863.     INX    H
  1864.     RET
  1865. ;
  1866. TRNRPD:    LXI    D,OPRDX    ;'DX'
  1867.     INX    H
  1868.     RET
  1869. ;
  1870. TRNRPH:    LXI    D,OPRBX    ;'BX'
  1871.     INX    H
  1872.     RET
  1873. ;
  1874. TRNRPP:    INX    H
  1875.     MOV    A,M
  1876.     ANI    5FH
  1877.     CPI    'S'
  1878.     JNZ    TRNRP4
  1879.     INX    H
  1880.     MOV    A,M
  1881.     ANI    5FH
  1882.     CPI    'W'
  1883.     JNZ    TRNRP3
  1884.     LXI    D,OPRAX    ;'AX'
  1885.     INX    H
  1886.     RET
  1887. ;
  1888. TRNRP3:    DCX    H
  1889. TRNRP4:    DCX    H
  1890.     JMP    TRNRP2
  1891. ;
  1892. TRNRPS:    INX    H
  1893.     MOV    A,M
  1894.     ANI    5FH
  1895.     CPI    'P'
  1896.     JNZ    TRNRP4
  1897.     LXI    D,OPRSP
  1898.     INX    H
  1899.     RET
  1900. ;
  1901. OPRAX    DB    'AX',0
  1902. OPRCX    DB    'CX',0
  1903. OPRDX    DB    'DX',0
  1904. OPRBX    DB    'BX',0
  1905. OPRSP    DB    'SP',0
  1906.  
  1907. ;
  1908. ;    Strange opcodes
  1909. ;
  1910. DOTDL:    LDA    OPCBUF+1
  1911.  
  1912.     LXI    H,CCZ    ;'Z '
  1913.     CPI    'E'
  1914.     JZ    DOTDL1
  1915.     LXI    H,CCNZ    ;'NZ'
  1916.     CPI    'N'
  1917.     JZ    DOTDL1
  1918.     LXI    H,CCC    ;'C '
  1919.     CPI    'L'
  1920.     JZ    DOTDL1
  1921.     LXI    H,CCNC    ;'NC'
  1922.  
  1923.     CPI    'G'
  1924.     JZ    DOTDL1
  1925.     LXI    H,CCZL
  1926.     CPI    'e'
  1927.     JZ    DOTDL1
  1928.     LXI    H,CCNZL
  1929.     CPI    'n'
  1930.     JZ    DOTDL1
  1931.     LXI    H,CCCL
  1932.     CPI    'l'
  1933.     JZ    DOTDL1
  1934.     LXI    H,CCNCL
  1935.  
  1936. DOTDL1:    MOV    A,M
  1937.     STA    OPCBUF+1
  1938.     INX    H
  1939.     MOV    A,M
  1940.     STA    OPCBUF+2
  1941.     RET
  1942. ;
  1943. CCZ    DB    'Z '
  1944. CCNZ    DB    'NZ'
  1945. CCC    DB    'C '
  1946. CCNC    DB    'NC'
  1947.  
  1948. CCZL    DB    'z '
  1949. CCNZL    DB    'nz'
  1950. CCCL    DB    'c '
  1951. CCNCL    DB    'nc'
  1952.  
  1953. ;
  1954. ;    Return conditional
  1955. ;    RC -> JNC $+3, RET
  1956. ;
  1957. DORET:    CALL    PUTOPC
  1958.     CALL    PUTHT    ; Could be PUTHTS
  1959.     LXI    H,REL3
  1960.     CALL    PUTLIN
  1961.     CALL    SEP
  1962.     LXI    H,OPRET
  1963.     CALL    PUTOPS
  1964.     JMP    PUTOPR
  1965. ;
  1966. REL3    DB    '$+3',0
  1967. OPRET    DB    'RET',0
  1968.  
  1969. ;
  1970. ;    Call conditional
  1971. ;    CC label -> JNC $+5, CALL label
  1972. ;
  1973. DOCALL:    CALL    PUTOPC
  1974.     CALL    PUTHT    ; Could be PUTHTS
  1975.  
  1976.     LXI    H,REL5
  1977.     CALL    PUTLIN
  1978.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  1979.     LXI    H,OPCALL
  1980.     CALL    PUTOPS
  1981.     CALL    PUTHTS
  1982.     JMP    PUTOPR
  1983. ;
  1984. REL5    DB    '$+5',0
  1985. OPCALL    DB    'CALL',0
  1986.  
  1987. ;
  1988. ;    Jump conditional
  1989. ;    JC label -> JNC $+5, JMP label
  1990. ;
  1991. DOJMP:    CALL    PUTOPC
  1992.     CALL    PUTHT    ; Could be PUTHTS
  1993.  
  1994.     LXI    H,REL5
  1995.     CALL    PUTLIN
  1996.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  1997.     LXI    H,OPJMP
  1998.     CALL    PUTOPS
  1999.     CALL    PUTHTS
  2000.     JMP    PUTOPR
  2001. ;
  2002. OPJMP    DB    'JMP',0
  2003.  
  2004. ;
  2005. ;    IN n -> IN AL,n
  2006. ;
  2007. DOIN:    JMP    DOIMM
  2008.  
  2009. ;
  2010. ;    LDA addr -> MOV AL,addr
  2011. ;
  2012. DOLDA:    JMP    DOIMM
  2013.  
  2014. ;
  2015. ;           XCHG BX,rp'
  2016. ;    LDAX rp -> MOV AL,[BX]
  2017. ;           XCHG BX,rp'
  2018. ;
  2019. DOLDAX:    LHLD    xOPRND
  2020.     CALL    TRNRP    ; DE -> trans, HL -> next
  2021.     JNZ    PUTCOD
  2022.  
  2023.     PUSH    H
  2024.     LXI    H,OPXCHG
  2025.     CALL    PUTOPS
  2026.     CALL    PUTHTS
  2027.     LXI    H,OPBXC
  2028.     CALL    PUTOPS
  2029.     XCHG
  2030.     PUSH    H
  2031.     CALL    PUTRND
  2032.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  2033.  
  2034.     LXI    H,OPMOV
  2035.     CALL    PUTOPS
  2036.     CALL    PUTHTS
  2037.     LXI    H,OPLDAX
  2038.     CALL    PUTOPS
  2039.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  2040.  
  2041.     LXI    H,OPXCHG
  2042.     CALL    PUTOPS
  2043.     CALL    PUTHTS
  2044.     LXI    H,OPBXC
  2045.     CALL    PUTOPS
  2046.     POP    H    ; HL -> rp'
  2047.     CALL    PUTRND
  2048.  
  2049.     POP    H
  2050.     JMP    PUTEND
  2051. ;
  2052. OPMOV    DB    'MOV',0
  2053. OPLDAX    DB    'AL,[BX]',0
  2054.  
  2055. ;
  2056. ;    LHLD addr -> MOV BX,addr
  2057. ;
  2058. DOLHLD:    CALL    PUTOPHT
  2059.     LXI    H,OPBXC    ; 'BX,'
  2060.     CALL    PUTOPS
  2061.     JMP    PUTOPR
  2062.  
  2063. ;
  2064. ;    OUT n -> OUT n,AL
  2065. ;
  2066. DOOUT:    CALL    PUTOPHT
  2067.     CALL    PUTEXP
  2068.     PUSH    H
  2069.     LXI    H,OPCAL    ; ',AL'
  2070.     JMP    DOSTA1
  2071.  
  2072. ;
  2073. ;    PCHL -> JMP BX
  2074. ;
  2075. DOPCHL:    CALL    PUTOPHT
  2076.     LXI    H,OPRBX    ; 'BX'
  2077.     CALL    PUTOPS
  2078.     JMP    PUTOPR
  2079.  
  2080. ;
  2081. ;    RST -> CALL 8*
  2082. ;
  2083. DORST:    CALL    PUTOPHT
  2084.     LXI    H,OPR8M    ;'8*'
  2085.     CALL    PUTOPS
  2086.     JMP    PUTOPR
  2087. ;
  2088. OPR8M    DB    '8*',0
  2089.  
  2090. ;
  2091. ;    SHLD addr -> MOV addr,BX
  2092. ;
  2093. DOSHLD:    CALL    PUTOPHT
  2094.     CALL    PUTEXP
  2095.     PUSH    H
  2096.     LXI    H,OPCBX    ; ',BX'
  2097.     JMP    DOSTA1
  2098. ;
  2099. OPCBX    DB    ',BX',0
  2100.  
  2101. ;
  2102. ;    SPHL -> MOV SP,BX
  2103. ;
  2104. DOSPHL:    CALL    PUTOPHT
  2105.     LXI    H,OPSPBX ; 'SP,BX'
  2106.     CALL    PUTOPS
  2107.     JMP    PUTOPR
  2108. ;
  2109. OPSPBX    DB    'SP,BX',0
  2110.  
  2111. ;
  2112. ;    STA addr -> MOV addr,AL
  2113. ;
  2114. DOSTA:    CALL    PUTOPHT
  2115.     CALL    PUTEXP
  2116.     PUSH    H
  2117.     LXI    H,OPCAL    ; ',AL'
  2118. DOSTA1:    CALL    PUTOPS
  2119.     POP    H
  2120.     JMP    PUTEND
  2121. ;
  2122. OPCAL    DB    ',AL',0
  2123.  
  2124. ;
  2125. ;           XCHG BX,rp'
  2126. ;    STAX rp -> MOV [BX],AL
  2127. ;           XCHG BX,rp'
  2128. ;
  2129. DOSTAX:    LHLD    xOPRND
  2130.     CALL    TRNRP    ; DE -> trans, HL -> next
  2131.     JNZ    PUTCOD
  2132.  
  2133.     PUSH    H
  2134.     LXI    H,OPXCHG
  2135.     CALL    PUTOPS
  2136.     CALL    PUTHTS
  2137.     LXI    H,OPBXC
  2138.     CALL    PUTOPS
  2139.     XCHG
  2140.     PUSH    H
  2141.     CALL    PUTRND
  2142.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  2143.  
  2144.     LXI    H,OPMOV
  2145.     CALL    PUTOPS
  2146.     CALL    PUTHTS
  2147.     LXI    H,OPSTAX
  2148.     CALL    PUTOPS
  2149.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  2150.  
  2151.     LXI    H,OPXCHG
  2152.     CALL    PUTOPS
  2153.     CALL    PUTHTS
  2154.     LXI    H,OPBXC
  2155.     CALL    PUTOPS
  2156.     POP    H    ; HL -> rp'
  2157.     CALL    PUTRND
  2158.  
  2159.     POP    H
  2160.     JMP    PUTEND
  2161. ;
  2162. OPSTAX    DB    '[BX],AL',0
  2163.  
  2164. ;
  2165. ;    XCHG -> XCHG BX,DX
  2166. ;
  2167. DOXCHG:    CALL    PUTOPHT
  2168.     LXI    H,OPBXDX ; 'BX,DX'
  2169.     CALL    PUTOPS
  2170.     JMP    PUTOPR
  2171. ;
  2172. OPBXDX    DB    'BX,DX',0
  2173.  
  2174. ;
  2175. ;        XCHG SP,BP
  2176. ;    XTHL -> XCHG [BP],BX
  2177. ;        XCHG SP,BP
  2178. ;
  2179. DOXTHL:    LXI    H,OPXCHG
  2180.     CALL    PUTOPS
  2181.     CALL    PUTHTS
  2182.     LXI    H,OPSPBP ; 'SP,BP'
  2183.     CALL    PUTOPS
  2184.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  2185.  
  2186.     LXI    H,OPXCHG
  2187.     CALL    PUTOPS
  2188.     CALL    PUTHTS
  2189.     LXI    H,OPXTHL
  2190.     CALL    PUTOPS
  2191.     CALL    SEP    ; SP,EP,SP or CR, LF, HT
  2192.  
  2193.     LXI    H,OPXCHG
  2194.     CALL    PUTOPS
  2195.     CALL    PUTHTS
  2196.     LXI    H,OPSPBP
  2197.     CALL    PUTOPS
  2198.     JMP    PUTOPR
  2199. ;
  2200. OPSPBP    DB    'SP,BP',0
  2201. OPXTHL    DB    '[BP],BX',0
  2202.  
  2203. ;
  2204. ;    CMA -> NOT AL
  2205. ;
  2206. DOCMA:    CALL    PUTOPHT
  2207.     LXI    H,ALREG
  2208.     CALL    PUTOPS
  2209.     JMP    PUTOPR
  2210.  
  2211. ;
  2212. ;    Put 'expression' to output file.
  2213. ;    'expression' is everything between
  2214. ;    (xOPRND) up to the tab or spaces before
  2215. ;    a ';' or CR.
  2216. ;
  2217. PUTEXP:    LHLD    xOPRND
  2218. PUTEX1:    MOV    A,M
  2219.  
  2220.     CPI    ';'
  2221.     JZ    PUTEX4
  2222.     CPI    CR
  2223.     JZ    PUTEX4
  2224.  
  2225.     CPI    '!'
  2226.     JZ    PUTEX3
  2227.  
  2228. PUTEX2:    INX    H
  2229.     JMP    PUTEX1
  2230.  
  2231. PUTEX3:    DCX    H
  2232.     MOV    A,M
  2233.     INX    H
  2234.     CPI    ' '
  2235.     JZ    PUTEX4
  2236.     CPI    HT
  2237.     JZ    PUTEX4
  2238.     JMP    PUTEX2
  2239.  
  2240. ;
  2241. PUTEX4:    DCX    H
  2242.     MOV    A,M
  2243.     CPI    ' '
  2244.     JZ    PUTEX4
  2245.     CPI    HT
  2246.     JZ    PUTEX4
  2247.     INX    H
  2248.     XCHG
  2249.     LHLD    xOPRND
  2250. PUTEX5:    MOV    A,D
  2251.     CMP    H
  2252.     JNZ    PUTEX6
  2253.     MOV    A,E
  2254.     CMP    L
  2255.     RZ
  2256. PUTEX6:    MOV    A,M
  2257.     CALL    PUTCHR
  2258.     INX    H
  2259.     JMP    PUTEX5
  2260.  
  2261. ;
  2262. ;    IFC -> IF
  2263. ;
  2264. DOIFC:    MVI    A,HT
  2265.     STA    ENDIFL
  2266.     JMP    DOUPS
  2267.  
  2268. ;
  2269. ;    ICL -> *INCL
  2270. ;
  2271. DOICL:    MVI    A,HT
  2272.     STA    ICLFLG
  2273.     JMP    DOUPS
  2274.  
  2275. ;
  2276. ;    LST -> LIST
  2277. ;
  2278. DOLST:    MVI    A,HT
  2279.     STA    LSTFLG
  2280.     JMP    DOUPS
  2281.  
  2282. ;
  2283. ;    MAC -> MACRO
  2284. ;
  2285. DOMAC:    MVI    A,HT
  2286.     STA    MACFLG
  2287. DOUPS:    CALL    PUTOPHT
  2288.     MVI    A,CR
  2289.     STA    UPSMSG
  2290.     JMP    PUTOPR
  2291.  
  2292. ;*******************************************************
  2293. ;
  2294. ;    File operations
  2295. ;
  2296. ;*******************************************************
  2297. ;
  2298. ;    Set up input and output FCB's from DFCB
  2299. ;
  2300. MAKFNS:    LXI    H,DFCB1
  2301.     LXI    D,INFCB
  2302.     LXI    B,FNLEN+1
  2303.     CALL    MOVIR
  2304.     MOV    A,M    ; typ specified ?
  2305.     CPI    ' '
  2306.     JZ    MKFNS1
  2307.     CPI    '?'
  2308.     JZ    MKFNS1
  2309.     LXI    B,3
  2310.     CALL    MOVIR
  2311. MKFNS1:
  2312.     LXI    H,DFCB1
  2313.     LXI    D,OUTFCB
  2314.     LXI    B,FNLEN+1
  2315.     CALL    MOVIR
  2316.  
  2317.     LDA    DFCB2    ;
  2318.     ORA    A    ; allows output to
  2319.     JZ    MKFNS2    ; different drive
  2320.     STA    OUTFCB    ; than input
  2321. MKFNS2:
  2322.     LDA    DFCB2+1    ;
  2323.     CPI    ' '    ;
  2324.     JZ    MKFNS3    ; allows output
  2325.     LXI    B,8    ; file to have
  2326.     LXI    D,OUTFCB+1 ; different name
  2327.     LXI    H,DFCB2+1 ; from input file
  2328.     CALL    MOVIR
  2329. MKFNS3:
  2330.     LDA    DFCB2+9
  2331.     CPI    ' '
  2332.     JZ    MKFNS4
  2333.     LXI    B,3
  2334.     LXI    D,OUTFCB+9
  2335.     LXI    H,DFCB2+9
  2336.     CALL    MOVIR
  2337. MKFNS4:
  2338.     LXI    D,PRFNM1
  2339.     CALL    PRTLIN
  2340.     LXI    H,INFCB
  2341.     CALL    PRFNAM
  2342.     LXI    D,PRFNM2
  2343.     CALL    PRTLIN
  2344.     LXI    H,OUTFCB
  2345.     CALL    PRFNAM
  2346.     LXI    D,CRLFMG
  2347.     CALL    PRTLIN
  2348.     RET
  2349.  
  2350. ;
  2351. ;    Print Filenames
  2352. ;
  2353. PRFNAM:    MOV    A,M    ; disk number
  2354.     ORA    A
  2355.     JNZ    PRFN1
  2356.     LDA    xCDISK
  2357. PRFN1:    ADI    '@'
  2358.     CALL    CONOUT
  2359.     MVI    A,':'
  2360.     CALL    CONOUT
  2361.     INX    H
  2362.     MVI    B,8
  2363.     CALL    PRFN
  2364.     MVI    A,'.'
  2365.     CALL    CONOUT
  2366.     MVI    B,3
  2367. PRFN:    MOV    A,M
  2368.     INX    H
  2369.     CPI    ' '
  2370.     CNZ    CONOUT
  2371.     DCR    B
  2372.     JNZ    PRFN
  2373.     RET
  2374. ;
  2375. PRFNM1    DB    'Source File: ',0
  2376. PRFNM2    DB    ',  Destination File: ',0
  2377.  
  2378. ;
  2379. ;    Open source file with ext ASM
  2380. ;
  2381. OPENIN:
  2382.     LXI    D,INFCB
  2383.     MVI    C,nOPEN
  2384.     CALL    BDOS
  2385.     CPI    NFF
  2386.     JZ    NSFERR
  2387.     MVI    A,RECLEN
  2388.     LXI    H,IBUFF+IBFLEN
  2389.     SHLD    xIBUFF
  2390.     RET
  2391. ;
  2392. NSFERR:    LXI    D,NSFMSG ;'No Source File'
  2393.     JMP    EREXIT
  2394. ;
  2395. NSFMSG    DB    'No Source File Found'
  2396.     DB    CR,LF,BEL,0
  2397. ;
  2398. INFCB    DB    0,0,0,0,0,0,0,0
  2399.     DB    0,'ASM',0,0,0,0
  2400.     DB    0,0,0,0,0,0,0,0
  2401.     DB    0,0,0,0,0,0,0,0
  2402.     DB    0
  2403.  
  2404. ;
  2405. ;    Create output file with ext Z80
  2406. ;
  2407. CREATO:
  2408.     LXI    D,OUTFCB
  2409.     MVI    C,nOPEN
  2410.     CALL    BDOS
  2411.     CPI    NFF
  2412.     JNZ    OFEERR
  2413. CREAT4:    LXI    D,OUTFCB
  2414.     MVI    C,nCREAT
  2415.     CALL    BDOS
  2416.     CPI    NFF
  2417.     JZ    NDSERR
  2418.     LXI    D,OUTFCB
  2419.     MVI    C,nOPEN
  2420.     CALL    BDOS
  2421.     MVI    A,RECLEN
  2422.     STA    OBUFCT
  2423.     LXI    H,OBUFF
  2424.     SHLD    xOBUFF
  2425.     RET
  2426. ;
  2427. NDSERR:    LXI    D,NDSMSG ;'No directory space'
  2428.     JMP    EREXIT
  2429. ;
  2430. NDSMSG    DB    'No Directory Space'
  2431.     DB    CR,LF,BEL,0
  2432. ;
  2433. OUTFCB    DB    0,0,0,0,0,0,0,0
  2434.     DB    0,'A86',0,0,0,0
  2435.     DB    0,0,0,0,0,0,0,0
  2436.     DB    0,0,0,0,0,0,0,0
  2437.     DB    0
  2438. ;
  2439. ;
  2440. OFEERR:    LXI    D,OFEMSG ;'Output file exists'
  2441.     CALL    PRTLIN
  2442.     CALL    CHKYES
  2443.     JNZ    ABORT
  2444.     LXI    D,OUTFCB
  2445.     MVI    C,nDEL
  2446.     CALL    BDOS
  2447.     JMP    CREAT4
  2448. ;
  2449. OFEMSG    DB    'Output File Already Exists'
  2450.     DB    ' -- Delete it and Continue ? (Y/N) '
  2451.     DB    BEL,0
  2452.  
  2453. ;*******************************************************
  2454. ;
  2455. ;    Put line at HL to output file until 0.
  2456. ;
  2457. PUTLIN:    MOV    A,M
  2458.     ANA    A
  2459.     RZ
  2460.     CALL    PUTCHR
  2461.     INX    H
  2462.     JMP    PUTLIN
  2463.  
  2464. ;
  2465. ;    Put spaces or tabs at HL to output
  2466. ;    file until non-(space or tab)
  2467. ;
  2468. PUTSPT:    MOV    A,M
  2469.     CPI    ' '
  2470.     JZ    PUTSP1
  2471.     CPI    HT
  2472.     RNZ
  2473. PUTSP1:    CALL    PUTCHR
  2474.     INX    H
  2475.     JMP    PUTSPT
  2476.  
  2477. ;
  2478. ;    Put statement separator to output file.
  2479. ;
  2480. SEP:    LHLD    SEPMSG
  2481.     JMP    PUTLIN
  2482. ;
  2483. SEPMSG    DW    NEWLSP
  2484. EXCLSP    DB    ' ! ',0
  2485. NEWLSP    DB    CR,LF,HT,0
  2486.  
  2487. ;
  2488. ;    Put CR, LF to output file.
  2489. ;
  2490. PCRLF:    MVI    A,CR
  2491.     CALL    PUTCHR
  2492.     MVI    A,LF
  2493.  
  2494. ;
  2495. ;    Put char in A to output file,
  2496. ;    update column number.
  2497. ;
  2498. PUTCHR:    PUSH    H
  2499.     PUSH    D
  2500.     PUSH    B
  2501.     PUSH    PSW
  2502.  
  2503.     STA    TEMP
  2504.     LHLD    xOBUFF
  2505.     CPI    EOT
  2506.     JNZ    PCHR0
  2507.     MVI    A,'!'
  2508. PCHR0:    MOV    M,A
  2509.     CPI    CR
  2510.     JZ    PUTCH0
  2511.     CPI    LF
  2512.     JZ    PUTCH0
  2513.     CPI    HT
  2514.     JNZ    PUTCH1
  2515.     LDA    COLNUM
  2516.     DCR    A
  2517.     ANI    NF8
  2518.     ADI    N09
  2519.     JMP    PUTCH2
  2520.  
  2521. PUTCH0:    MVI    A,1
  2522.     JMP    PUTCH2
  2523. ;
  2524. PUTCH1:    LDA    COLNUM
  2525.     INR    A
  2526. PUTCH2:    STA    COLNUM
  2527.  
  2528.     INX    H    ;inc obuff ptr
  2529.     LDA    OBUFCT
  2530.     DCR    A    ;dec obuff count
  2531.     JNZ    PTCH21
  2532.     MVI    A,RECLEN
  2533. PTCH21:    STA    OBUFCT
  2534.     MOV    A,H
  2535.     CPI    (OBUFF+OBFLEN)/256
  2536.     JNZ    PUTCH4
  2537.     MOV    A,L
  2538.     CPI    (OBUFF+OBFLEN) MOD 256
  2539.  
  2540.     JNZ    PUTCH4
  2541.     LXI    D,OBUFF
  2542. PUTCH3:
  2543.     MVI    C,nDMA
  2544.     PUSH    D
  2545.     CALL    BDOS
  2546.     POP    D
  2547.  
  2548.     XCHG
  2549.  
  2550.     LXI    D,OUTFCB
  2551.     CALL    WRTREC    ;write record
  2552.  
  2553.     LXI    D,RECLEN
  2554.     DAD    D
  2555.     XCHG
  2556.     MOV    A,D
  2557.     CPI    (OBUFF+OBFLEN)/256
  2558.     JNZ    PUTCH3
  2559.     MOV    A,E
  2560.     CPI    (OBUFF+OBFLEN) MOD 256
  2561.     JNZ    PUTCH3
  2562.  
  2563.     LXI    H,OBUFF
  2564.  
  2565. PUTCH4:    SHLD    xOBUFF
  2566.     POP    PSW
  2567.     POP    B
  2568.     POP    D
  2569.     POP    H
  2570.     RET
  2571. ;
  2572. TEMP    DB    0
  2573.  
  2574. ;
  2575. ;    Write record.
  2576. ;
  2577. WRTREC:    MVI    C,nWRNR
  2578.     PUSH    H
  2579.     CALL    BDOS
  2580.     POP    H
  2581.     ANA    A
  2582.     RZ
  2583.     LXI    D,OFWMSG ;'output file write error'
  2584.     JMP    EREXIT
  2585. ;
  2586. OFWMSG    DB    'Output File Write Error'
  2587.     DB    CR,LF,BEL,0
  2588.  
  2589. ;
  2590. ;    Fill rest of obuff with EOF,
  2591. ;    write record, and close file.
  2592. ;
  2593. CLOSEO:    MVI    A,EOF
  2594.     CALL    PUTCHR
  2595.     LDA    OBUFCT
  2596.     CPI    RECLEN
  2597.     JNZ    CLOSEO
  2598. ;
  2599. CLOSE1:
  2600.     LXI    D,OBUFF
  2601.     LHLD    xOBUFF
  2602.     MOV    A,H
  2603.     CMP    D
  2604.     JNZ    CLOSE3
  2605.     MOV    A,L
  2606.     CMP    E
  2607.     JNZ    CLOSE3
  2608. CLOSE2:
  2609.     LXI    D,OUTFCB
  2610.     MVI    C,nCLOSE
  2611.     JMP    BDOS
  2612. ;
  2613. CLOSE3:    MVI    C,nDMA
  2614.     PUSH    D
  2615.     CALL    BDOS
  2616.     POP    D
  2617.     XCHG
  2618.     LXI    D,OUTFCB
  2619.     CALL    WRTREC
  2620.     LXI    D,RECLEN
  2621.     DAD    D
  2622.     XCHG
  2623.     LDA    xOBUFF+1
  2624.     CMP    D
  2625.     JNZ    CLOSE3
  2626.     LDA    xOBUFF
  2627.     CMP    E
  2628.     JNZ    CLOSE3
  2629.     JMP    CLOSE2
  2630.  
  2631. ;
  2632. ;    Print line at DE until 0
  2633. ;    on console.
  2634. ;
  2635. PRTLIN:    LDAX    D
  2636.     ANA    A
  2637.     RZ
  2638.     CALL    CONOUT
  2639.     INX    D
  2640.     JMP    PRTLIN
  2641.  
  2642. ;
  2643. ;    Console Output character in A.
  2644. ;
  2645. CONOUT:    PUSH    PSW
  2646.     PUSH    B
  2647.     PUSH    D
  2648.     PUSH    H
  2649.     MOV    E,A
  2650.     MVI    D,N00
  2651.     MVI    C,nCOUT
  2652.     CALL    BDOS
  2653.     POP    H
  2654.     POP    D
  2655.     POP    B
  2656.     POP    PSW
  2657.     RET
  2658.  
  2659. ;
  2660. ;    Get char from CONSOLE and return
  2661. ;    Z set if char.AND.5FH = 'Y'
  2662. ;
  2663. CHKYES:    MVI    C,nCIN
  2664.     CALL    BDOS
  2665.     PUSH    PSW
  2666.     CALL    CRLF
  2667.     POP    PSW
  2668.     ANI    5FH
  2669.     CPI    'Y'
  2670.     RET
  2671.  
  2672. ;
  2673. ;    Return Z if no char available,
  2674. ;    otherwise, get char in A.
  2675. ;
  2676. CHKIN:    MVI    C,nCDAV
  2677.     CALL    BDOS
  2678.     ORA    A
  2679.     RZ
  2680.     MVI    C,nCIN
  2681.     CALL    BDOS
  2682.     RET
  2683.  
  2684. ;
  2685. ;
  2686. ;
  2687. CRLF:    LXI    D,CRLFMG
  2688.     JMP    PRTLIN
  2689. ;
  2690. CRLFMG    DB    CR,LF,0
  2691.  
  2692. ;
  2693. ;    Convert upper to lower case in A.
  2694. ;
  2695. LCASE:    CPI    'A'
  2696.     RC
  2697.     CPI    'Z'+1
  2698.     RNC
  2699.     ORI    20H
  2700.     RET
  2701.  
  2702. ;
  2703. ;    Convert lower case to upper case in A.
  2704. ;
  2705. UCASE:    CPI    'a'
  2706.     RC
  2707.     CPI    'z'+1
  2708.     RNC
  2709.     ANI    5FH
  2710.     RET
  2711.  
  2712. ;
  2713. ;    Print activity dot every 100 lines.
  2714. ;
  2715. PDOT:    LDA    LNCNT
  2716.     DCR    A
  2717.     STA    LNCNT
  2718.     RNZ
  2719.     MVI    A,'.'
  2720.     CALL    CONOUT
  2721.     MVI    A,100    ; Dot every 100 lines
  2722.     STA    LNCNT
  2723.  
  2724.     LDA    DOTCNT
  2725.     DCR    A
  2726.     STA    DOTCNT
  2727.     JNZ    PDOT1
  2728.     MVI    A,' '
  2729.     CALL    CONOUT
  2730.     MVI    A,10    ; Space every 10 dots
  2731.     STA    DOTCNT
  2732.  
  2733. PDOT1:    LDA    NLCNT
  2734.     DCR    A
  2735.     STA    NLCNT
  2736.     RNZ
  2737.     CALL    CRLF
  2738.     MVI    A,50    ; 50 dots per line
  2739.     STA    NLCNT
  2740.     RET
  2741. ;
  2742. LNCNT    DB    100    ; dot every 100 lines
  2743. DOTCNT    DB    10    ; space every 10 dots
  2744. NLCNT    DB    50    ; 50 dots per line
  2745.  
  2746. ;
  2747. ;    Uninitialized storage.
  2748. ;
  2749. xCDISK    DS    1
  2750. SPBDOS    DS    2
  2751.     DS    STCKLN
  2752. STACK    EQU    $
  2753. COLNUM    DS    1
  2754. xOPCOD    DS    2
  2755. OPCBUF    DS    OPBFLN
  2756. xOPRND    DS    2
  2757. xOBUFF    DS    2
  2758. OBUFCT    DS    1
  2759. OBUFF    DS    OBFLEN
  2760. LBUFF    DS    LBUFLN+3
  2761. xIBUFF    DS    2
  2762. IBUFF    DS    IBFLEN
  2763.  
  2764.     END    START
  2765. 
  2766. ;
  2767. CLOSEO:    MVI    A,EOF
  2768.     CALL    PUTCHR
  2769.     LDA    OBU